Fórmula Mediana Se – Excel e Google Planilhas

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Luciano Farina

Last updated on July 15, 2023

Este tutorial vai demonstrar como calcular o valor mediano que atende a determinados critérios no Excel e no Google Planilhas.

mf mediana se

Função MED

A função MED calcula o valor mediano (valor central de um conjunto de dados ordenados).

=MED(C2:C10)

med 2

Entretanto, não há uma função “Mediana Se” para calcular o valor mediano somente para números que atendam a determinados critérios.

Observação: Você deve estar familiarizado com a função MÉDIASES, que calculará a média para números que atendam a determinados critérios. Não há alternativa para a mediana.

Mediana Se – Fórmula de Matriz

Para calcular a “Mediana se”, devemos usar uma fórmula de matriz com a função SE dentro da função MED:

=MED(SE($A$2:$A$10=$E2; $C$2:$C$10))

med se matriz 2

Vamos examinar essa fórmula…

Excel 2019 e Anteriores

No Office 365 e nas versões do Excel posteriores a 2019, você pode simplesmente inserir a fórmula acima como faria normalmente (pressionando ENTER).

No entanto, no Excel 2019 e versões anteriores, você deve inserir a fórmula pressionando CTRL + SHIFT + ENTER. Depois de fazer isso, você notará que aparecerão colchetes ao redor da fórmula:

{=MED(SE($A$2:$A$10=$E2; $C$2:$C$10)}

Importante: não escreva você mesmo esses colchetes, eles devem ser inseridos somente com CTRL + SHIFT + ENTER.

Como a Fórmula Funciona?

Lembre-se de que essa é a nossa fórmula:

{=MED(SE($A$2:$A$10=$E2; $C$2:$C$10)}

A fórmula funciona avaliando os critérios de cada valor como VERDADEIRO ou FALSO.

=MED(SE({FALSO;VERDADEIRO;FALSO;FALSO;VERDADEIRO;FALSO;VERDADEIRO;VERDADEIRO;FALSO};{1287;1205;1243;1482;1261;1042;1090;1748;1909}))

A função IF substitui cada VERDADEIRO pelos valores reais.

=MED({FALSO;1205;FALSO;FALSO;1261;FALSO;1090;1748;FALSO})

Agora, a função MED ignora os valores FALSOS e calcula a mediana dos valores restantes (1233 é a média dos dois valores intermediários: 1205 e 1261).

Mediana Se – Vários critérios

Você também pode calcular uma mediana com base em vários critérios usando a lógica booleana.

Vamos dar uma olhada em um novo conjunto de dados com as colunas Localização, Ano e Estoque:

tabela med

Agora, aqui está a fórmula para calcular a mediana com base em vários critérios:

=MED(SE((A2:A4="B")*(B2:B4=2008);C2:C4))

med se 1

Observe que aqui multiplicamos dois conjuntos de critérios:

(A2:A4="b")*(B2:B4=2008)

Se ambos os critérios forem VERDADEIROS, ele será calculado como VERDADEIRO, mas se um (ou mais) critérios forem FALSOS, ele será calculado como FALSO.

Fórmula da Mediana Se no Planilhas Google

Todos os exemplos acima funcionam da mesma forma no Planilhas Google, exceto que sua fórmula deve estar contida na função ARRAYFORMULA (porque é uma fórmula de matriz).

=ARRAYFORMULA(MEDIAN(IF($A$2:$A$10=$E2, $C$2:$C$10)))

med se google