Median-Wenn-Formel – Excel & Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie in Excel und Google Sheets den Medianwert, der bestimmte Kriterien erfüllt, berechnen können.

Die MEDIAN-Funktion

Die MEDIAN-Funktion berechnet den Medianwert.

=MEDIAN(C2:C10)

Es gibt jedoch keine eingebaute MEDIAN-WENN-Funktion, die den Medianwert nur für Zahlen berechnet, die bestimmte Kriterien erfüllen.

Hinweis: Sie sind vielleicht mit der Funktion MITTELWERTWENNS vertraut, die den Durchschnitt für Zahlen berechnet, die bestimmte Kriterien erfüllen. Es gibt keine Median-Alternative.

MEDIAN-WENN – Array-Formel

Um „MEDIAN-WENN“ zu berechnen, müssen wir also eine Array-Formel mit der WENN-Funktion innerhalb der MEDIAN-Funktion verwenden:

=MEDIAN(WENN($A$2:$A$10=$E2; $C$2:$C$10))

Lassen Sie uns diese Formel durchgehen:

Excel 2019 und ältere Versionen

In Office 365 und Versionen von Excel nach 2019 können Sie die obige Formel einfach wie gewohnt eingeben (durch Drücken von EINGABE).

In Excel 2019 und früheren Versionen müssen Sie die Formel jedoch durch Drücken von STRG + UMSCHALTTASTE + EINGABE eingeben. Danach werden Sie feststellen, dass geschweifte Klammern um die Formel herum erscheinen:

{=MEDIAN(WENN($A$2:$A$10=$E2; $C$2:$C$10))}

Wichtig: Schreiben Sie diese geschweiften Klammern nicht selbst. Sie dürfen nur mit STRG + UMSCHALTTASTE + EINGABE eingegeben werden.

Wie funktioniert die Formel?

Erinnern Sie sich an unsere Formel:

{=MEDIAN(WENN($A$2:$A$10=$E2; $C$2:$C$10))}

Die Formel funktioniert, indem sie die Kriterien für jeden Wert als WAHR oder FALSCH bewertet.

=MEDIAN(WENN({FALSCH;WAHR;FALSCH;FALSCH;WAHR;FALSCH;WAHR;WAHR;FALSCH};{1287;1205;1243;1482;1261;1042;1090;1748;1909}))

Die WENN-Funktion ersetzt WAHR durch die tatsächlichen Werte.

=MEDIAN({FALSCH;1205;FALSCH;FALSCH;1261;FALSCH;1090;1748;FALSCH})

Nun ignoriert die MEDIAN-Funktion die FALSCH-Werte und berechnet den Median der verbleibenden Werte (1233 ist der Durchschnitt der beiden mittleren Werte: 1205 und 1261).

MEDIAN-WENN – Mehrere Kriterien

Sie können auch einen Median auf der Basis mehrerer Kriterien berechnen, indem Sie die Boolesche Logik verwenden.

Schauen wir uns einen neuen Datensatz mit den Spalten Ort, Jahr und Bestand an:

Hier ist die Formel zur Berechnung des Medians auf der Basis mehrerer Kriterien:

=MEDIAN(WENN((A2:A4="B")*(B2:B4=2008);C2:C4))

Beachten Sie, dass wir hier zwei Gruppen von Kriterien miteinander multiplizieren:

(A2:A4="b")*(B2:B4=2008)

Wenn beide Kriterien WAHR sind, wird das Ergebnis als WAHR berechnet, aber wenn eines oder mehrere Kriterien FALSCH sind, wird es als FALSCH berechnet.

MEDIAN-WENN-Formel in Google Sheets

Alle oben genannten Beispiele funktionieren in Google Sheets genauso wie in Excel mit der Ausnahme, dass Ihre Formel innerhalb der ArrayFormula-Funktion enthalten sein muss (weil es sich um eine Array-Formel handelt).

=ArrayFormula(MEDIAN(WENN($A$2:$A$10=$E2; $C$2:$C$10)))