Übersprungene Zahlen in Folge auflisten – Excel & Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie fehlende Zahlen in einem Bereich auflisten können.

Übersprungene Zahlen in Folge auflisten

Um fehlende Zahlen in einer Liste zu finden, können wir die folgende Formel verwenden:

=KKLEINSTE(WENN(ZÄHLENWENN(B3:B8;ZEILE(1:6))=0;ZEILE(1:6);"");ZEILE(B1))

Anmerkungen:

• Dies ist eine Array-Formel! Wenn Sie Excel 2019 und eine ältere Version verwenden, müssen Sie die Formel eingeben, indem Sie STRG+UMSCHALTTASTE+EINGABE drücken. Sie wissen, dass die Formel richtig eingegeben wurde, wenn Sie geschweifte Klammern darum herum sehen.
• Diese Formel funktioniert nur mit positiven ganzen Zahlen (Integer).

Wie funktioniert die Formel?

Zunächst wird die ZEILE-Funktion verwendet, um eine Reihe von Zahlen zu erzeugen:

{1;2;3;4;5;6}

Sie könnten diese Zahlenreihe auch manuell eingeben:

=KKLEINSTE(WENN(ZÄHLENWENN($B$3:$B$8;{1;2;3;4;5;6})=0;{1;2;3;4;5;6};"");ZEILE(B1))

Als Nächstes zählt die Funktion ZÄHLENWENN die Werte, wenn sie mit einem im Array gefundenen Wert übereinstimmen.

Um dies zu veranschaulichen, wandeln wir zunächst den Bereich $B$3:$B$8 in sein Wertefeld {3;2;0;6;0;5} um:

=KKLEINSTE(WENN(ZÄHLENWENN({3;2;0;6;0;5};{1;2;3;4;5;6})=0;{1;2;3;4;5;6};"");ZEILE(B1))

Als nächstes führen wir die Operation ZÄHLENWENN durch:

=KKLEINSTE(WENN({0;1;1;0;1;1}=0;{1;2;3;4;5;6};"");ZEILE(B1))

Wenn kein Wert gefunden wird, wird 0 ausgegeben. Die WENN-Funktion prüft, ob der Wert NICHT gefunden wurde und gibt in diesem Fall den Wert aus dem Array zurück, andernfalls wird ein Leerzeichen ausgegeben:

=KKLEINSTE({1;"";"";4;"";""};ZEILE(B1))

Zuletzt gibt die Funktion KKLEINSTE  den kleinsten fehlenden Wert in der ausgewählten Zelle zurück.

=KKLEINSTE({1;"";"";4;"";""};{1})

={1}

Tipp:

Um den Fehler #ZAHL! zu vermeiden, Schließen Sie Ihre Formel in die Funktion WENNFEHLER ein:

=WENNFEHLER(KKLEINSTE(WENN(ZÄHLENWENN(B3:B8;ZEILE(1:6))=0;ZEILE(1:6);"");ZEILE(B1));"")

Übersprungene Zahlen in Google Sheets in Folge auflisten

Alle oben erläuterten Beispiele funktionieren in Google Sheets genauso wie in Excel.