Fórmula SI – Sentencias IF Then – Excel y Google Sheets

Este tutorial muestra cómo utilizar la  Función SI en Excel y Google Sheets para crear sentencias If Then.

 

Visión General de la Función SI

La función SI comprueba si se cumple una condición. Si es VERDADERO hace una cosa, si es FALSO hace otra.

Cómo Utilizar la Función SI

Aquí hay un ejemplo muy básico para que puedas ver lo que quiero decir. Intenta escribir lo siguiente en Excel:

=SI( 2 + 2 = 4; "Es Verdadero"; "¡Es Falso!")

Como 2 + 2 es de hecho igual a 4, Excel devolverá «Es Verdadero». Si utilizamos esto

=SI( 2 + 2 = 5; "Es verdadero"; "¡Es falso!")

Ahora Excel devolverá «¡Es falso!», porque 2 + 2 no es igual a 5.

Así es como se puede utilizar la sentencia SI en una hoja de cálculo.

=SI(C4>D4;"Si";"No")

Tienes un bar de deportes y estableces límites de fichas individuales para diferentes clientes. Has configurado esta hoja de cálculo para comprobar si cada cliente ha superado su límite, en cuyo caso le cortarás el grifo hasta que pague su cuenta.

Se comprueba si C4-D4 (el importe de la cuenta actual menos el límite) es mayor que 0. Esta es la prueba lógica. Si esto es cierto, SI devuelve «Sí» – debe cortarles el paso. Si esto es falso, SI devuelve «No» – usted los deja seguir bebiendo.

¿Qué Puede Devolver SI?

Arriba devolvimos una cadena de texto, «Sí» o «No». Pero también se pueden devolver números, o incluso otras fórmulas.

Digamos que algunos de sus clientes están acumulando grandes cuentas. Para disuadirlos, va a empezar a cobrar intereses a los clientes que superen su límite.

Para ello puede utilizar SI:

=SI(C4>D4;C4*0.03;0)

 

Si la cuenta es superior al límite, devuelve la cuenta multiplicada por 0,03, lo que devuelve el 3% de la cuenta. En caso contrario, devuelve 0: no han superado su ficha, por lo que no cobrarás intereses.

Uso de SI con Y

Puede combinar SI con la función Y de Excel para probar más de una condición. Excel sólo devolverá VERDADERO si TODAS las pruebas son verdaderas.

Así que implementó su tasa de interés. Pero algunos de sus clientes habituales se quejan. Siempre han pagado sus cuentas en el pasado, ¿por qué los reprime ahora? Se te ocurre una solución: no cobrarás intereses a ciertos clientes de confianza.

Creas una nueva columna en tu hoja de cálculo para identificar a los clientes de confianza y actualizas tu declaración SI con una función Y:

=SI(Y(C4>D4; F4="No");C4*0.03;0)

Veamos la parte Y por separado:

Y(C4>D4; F4="No")

Observe las dos condiciones:

• C4>D4: comprueba si están por encima de su límite de fichas, como antes
• F4=»No»: esto es lo nuevo, comprobar si no son clientes de confianza

Así que ahora sólo devolvemos el tipo de interés si el cliente está por encima de su ficha, Y tenemos «No» en la columna de cliente de confianza. Tus clientes habituales vuelven a estar contentos.

Uso de SI con O

La función O le permite comprobar más de una condición, devolviendo VERDADERO si se cumple alguna de ellas.

Tal vez el hecho de que los clientes se pasen de la cuenta no es la única razón por la que les cortas el grifo. Tal vez usted da a algunas personas una prohibición temporal por otras razones, el juego en el local tal vez.

Así que añades una nueva columna para identificar a los clientes prohibidos, y actualizas tu columna «¿Corte?» con una prueba O:

=SI(O(C4>D4;E4="Si");"Si";"No")

Mirando sólo la parte O:

O(C4>D4;E4="Si")

Hay dos condiciones:

• C4>D4: se comprueba si se ha superado el límite de la cuenta
• F4=»Sí»: la nueva parte, comprobando si están actualmente prohibidos

Esto se evaluará como verdadero si están por encima de su ficha, o si hay un «Sí» en la columna E. Como puede ver, Harry está cortado ahora, aunque no está por encima de su límite de ficha.

Usando SI con XO

La función XO devuelve VERDADERO si sólo se cumple una condición. Si se cumple más de una condición (o no se cumplen las condiciones). Devuelve FALSE.

Un ejemplo puede hacer esto más claro. Imagine que quiere empezar a dar bonos mensuales a su personal :

• Si venden más de $800 en comida, o más de $800 en bebidas, les darás una media bonificación
• Si venden más de $800 en ambos, les darás una bonificación completa
• Si venden menos de $800 en ambos, no reciben ninguna bonificación.

Ya sabe cómo calcular si reciben la bonificación completa. Sólo tiene que utilizar SI con Y, como se ha descrito anteriormente.

=SI(Y(C4>800;D4>800);"SI";"No")

Pero, ¿cómo se puede saber quién recibe la mitad de la bonificación? Ahí es donde entra en juego XO:

=SI(XO(C4>=800;D4>=800);"Si";"No")

Como puedes ver, las ventas de bebidas de Woody superaron los $800, pero no las de comida. Por lo tanto, recibe la mitad de la bonificación. Lo contrario ocurre con el entrenador. Diane y Carla vendieron más de $800 en ambos casos, por lo que no obtienen la media bonificación (ambos argumentos son VERDADERO), y Rebecca ganó por debajo del umbral en ambos casos (ambos argumentos FALSOS), por lo que la fórmula vuelve a dar un «No».

Uso de SI con NO

La función NO invierte el resultado de una prueba lógica. En otras palabras, comprueba si una condición no se ha cumplido. Puede utilizarla con SI de la siguiente manera

=SI(Y(C3>=1985;NO(D3="Steven Spielberg"));"Mirar"; "No Mirar")

Aquí tenemos una tabla con datos sobre algunas películas de los años 80. Queremos identificar las películas estrenadas en o después de 1985, que no fueron dirigidas por Steven Spielberg.

Como NO está anidado dentro de una función Y, Excel evaluará primero esa función. Luego utilizará el resultado como parte de la función Y.

Declaraciones SI Anidadas

También puede devolver una sentencia SI dentro de su sentencia SI. Esto le permite realizar cálculos más complejos.

Volvamos a nuestra tabla de clientes. Imagínese que quiere clasificar a los clientes en función de su nivel de deuda con usted:

• 0$: Ninguno
• Hasta 500$: Bajo
• de $500 a $1000: Media
• Más de $1000: Alto

Puede hacerlo «anidando» sentencias SI:

=SI(C4=0;"Ninguno";SI(C4<=500;"Bajo";SI(C4<=1000;"Medio";SI(C4>1000;"Alto"; "Desconocido"))))

Es más fácil de entender si pone las declaraciones SI en líneas separadas(ALT + ENTER en Windows, CTRL + COMMAND + ENTER en Macs):

=
SI(C4=0;"Ninguno";
SI(C4<=500;"Bajo";
SI(C4<=1000;"Medio";
SI(C4>1000;"Alto"; "Desconocido"))))

Si C4 es 0, devolvemos «Ninguno». En caso contrario, pasamos a la siguiente sentencia SI. SI C4 es igual o inferior a 500, devolvemos «Bajo». En caso contrario, pasamos a la siguiente sentencia SI… y así sucesivamente.

Simplificación de Sentencias SI Complejas con Columnas Auxiliares

Si tiene múltiples sentencias SI anidadas, y está lanzando funciones lógicas también, sus fórmulas pueden volverse muy difíciles de leer, probar y actualizar.

Esto es especialmente importante si otras personas van a utilizar la hoja de cálculo. Lo que tiene sentido en tu cabeza, puede no ser tan obvio para otros.

Las columnas auxiliares son una buena forma de evitar este problema.

Eres un analista en el departamento financiero de una gran empresa. Te han pedido que crees una hoja de cálculo que compruebe si cada empleado tiene derecho a la pensión de la empresa.

Los criterios son los siguientes:

 

Si tienes menos de 55 años, necesitas 30 años de servicio para poder optar a la pensión. Si tiene entre 55 y 59 años, necesita 15 años de servicio. Y así sucesivamente, hasta los 65 años, en los que puedes optar a la pensión sin importar el tiempo que hayas trabajado. Podrías utilizar una única y compleja sentencia SI para resolver este problema:

=SI(O(F4>=65;Y(F4>=62;G4>=5);Y(F4>=60;G4>=10);Y(F4>=55;G4>=15);G4>30);"Elegible";"No Elegible")

¡Uf! Es un poco difícil de entender, ¿verdad? Un enfoque mejor sería utilizar columnas de ayuda. Aquí tenemos cinco pruebas lógicas, correspondientes a cada fila de la tabla de criterios. Esto es más fácil de ver si añadimos saltos de línea a la fórmula, como hemos comentado antes:

=SI(
O(F4>=65;
Y(F4>=62;G4>=5);
Y(F4>=60;G4>=10);
Y(F4>=55;G4>=15);
G4>30);
"Elegible";"No Elegible")

Así, podemos dividir estas cinco pruebas en columnas separadas, y luego simplemente comprobar si alguna de ellas es verdadera:

Cada columna de la tabla de E a I contiene cada uno de nuestros criterios por separado. Entonces en J4 tenemos la siguiente fórmula

=SI(CONTAR.SI(E4:I4;VERDADERO);"Elegible";"No Elegible")

Aquí tenemos una sentencia SI, y la prueba lógica utiliza CONTAR.SI para contar el número de celdas dentro de E4:I4 que contienen VERDADERO.

Si CONTAR.SI no encuentra un valor VERDADERO, devolverá 0, que SI interpreta como FALSO, por lo que el SI devuelve «No elegible».

Si CONTAR.SI sí encuentra algún valor VERDADERO, devolverá el número de ellos. SI interpreta cualquier número distinto de 0 como VERDADERO, por lo que devuelve «Elegible».

Dividir las pruebas lógicas de esta manera hace que la fórmula sea más fácil de leer, y si algo va mal en ella, es mucho más fácil detectar dónde está el error.

Uso de la Agrupación para Ocultar las Columnas Auxiliares

Las columnas auxiliaresel manejo de la fórmula, pero una vez que se han colocado y se sabe que funcionan correctamente, a menudo sólo ocupan espacio en la hoja de cálculo sin añadir ninguna información útil.

Podrías ocultar las columnas, pero esto puede acarrear problemas porque las columnas ocultas son difíciles de detectar, a no ser que te fijes bien en las cabeceras de las columnas.

Una opción mejor es la agrupación. Selecciona las columnas que quieres agrupar, en nuestro caso E:I. A continuación, pulsa ALT + SHIFT + FLECHA DERECHA en Windows, o COMANDO + SHIFT + K en Mac. También puedes ir a la pestaña «Datos» de la cinta de opciones y seleccionar «Agrupar» en la sección «Esquema».

Verás que el grupo aparece encima de las cabeceras de las columnas, así:

A continuación, basta con pulsar el botón «-» para ocultar las columnas:

La Función SI.CONJUNTO

Las sentencias SI anidadas son muy útiles cuando necesita realizar comparaciones lógicas más complejas, y necesita hacerlo en una celda. Sin embargo, pueden complicarse a medida que se alargan, y pueden ser difíciles de leer y actualizar en su pantalla.

A partir de Excel 2019 y Excel 365, Microsoft introdujo otra función, la Función SI.CONJUNTO, para ayudar a que esto sea un poco más fácil de manejar. El ejemplo de SI anidado anterior podría lograrse con SI.CONJUNTO así:

=SI.CONJUNTO(
C4=0; "Ninguno";
C4<=500; "Bajo";
C4<=1000; "Medio";
C4>1000; "Alto";
VERDADERO; "Desconocido";
)

Puede leerlo todo en la página principal de la función SI.CONJUNTO de Excel <<enlace>>.

Uso de SI con Formato Condicional

La función de Formato Condicional de Excel le permite dar formato a una celda de diferentes maneras dependiendo de su contenido. Dado que el SI devuelve diferentes valores basados en nuestra prueba lógica, podríamos querer usar el Formato Condicional con la Función SI  para hacer que estos diferentes valores sean más fáciles de ver.

Así que volvamos a nuestra tabla de bonos del personal de antes.

Devolvemos «Sí» o «No» en función de la bonificación que queramos dar. Esto nos dice lo que necesitamos saber, pero la información no salta a la vista. Intentemos arreglar eso. Así es como lo harías:

• Seleccione el rango de celdas que contiene sus sentencias SI. En nuestro caso es E4:F8.
• Haga clic en «Formato condicional» en la sección «Estilos» de la pestaña «Inicio» de la cinta.
• Haz clic en «Resaltar reglas de celdas» y luego en «Igual a».
• Escribe «Sí» (o cualquier valor de retorno que necesites) en la primera casilla, y luego elige el formato que quieras en la segunda casilla. (Yo elegiré el verde para esto).
• Repita para todos sus valores de retorno (también pondré los valores «No» en rojo)

Este es el resultado:

 

Usando SI en Fórmulas de Matriz

Una matriz es un rango de valores, y en Excel las matrices se representan como valores separados por comas encerrados entre llaves, como por ejemplo

{1;2;3;4;5}

Lo bueno de las matrices es que te permiten realizar un cálculo sobre cada valor del rango y luego devolver el resultado. Por ejemplo, la función SUMAPRODUCTO toma dos matrices, las multiplica y suma los resultados. Así que esta fórmula:

=SUMAPRODUCTO({1;2;3};{4;5;6})

…devuelve 32. ¿Por qué? Vamos a trabajar en ello:

1 * 4 = 4
2 * 5 = 10
3 * 6 = 18
4 + 10 + 18 = 32

Podemos introducir una sentencia SI en este cuadro, de forma que cada una de estas multiplicaciones sólo se produzca si una prueba lógica devuelve verdadero. Por ejemplo, tomemos estos datos:

 

Si quisieras calcular la comisión total de cada gestor de ventas, utilizarías lo siguiente

=SUMAPRODUCTO(SI($C$3:$C$11=$G3;$D$3:$D$11*$E$3:$E$11))

Nota: En Excel 2019 y anteriores, tienes que pulsar CTRL + SHIFT + ENTERpara convertir esto en una fórmula de matriz. Terminaríamos con algo así:

 

Desglosando esto, la columna «Gerente» es la columna C, y en este ejemplo, el nombre de Olivia está en G3. Así que la prueba lógica es:

$C$3:$C$11=$G3

En español, si el nombre de la columna C es igual a lo que hay en G3 («Olivia»), multiplica los valores de las columnas D y E de esa fila. En caso contrario, no los multipliques. Luego, suma todos los resultados.

Puedes aprender más sobre esta fórmula en la página principal de la fórmula SUMAPRODUCTO SI.

SI en Google Sheets

La función IF funciona exactamente igual en Google Sheets que en Excel:

 

Sentencias SI de VBA

También puede utilizar las  sentencias If en VBA. Haga clic en el enlace para aprender más, pero aquí hay un ejemplo sencillo:

Sub Prueba_IF()
    If Range("a1").Value < 0 Then
      Range("b1").Value = "Negativo"
    End If
End If

Este código comprobará si el valor de una celda es negativo. Si es así, escribirá «Negativo» en la siguiente celda.