WENN, ISTNV & WENNNV in SVERWEIS – Excel & Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie den #NV-Fehler bei SVERWEIS in Excel und Google Sheets behandeln können. Wenn Sie Zugriff auf die XVERWEIS-Funktion haben, lesen Sie unseren Artikel zur Behandlung von XVERWEIS-Fehlern.

WENNNV in SVERWEIS

Wenn Sie einen Wert mit der SVERWEIS-Funktion nachschlagen und er nicht gefunden wird, gibt SVERWEIS den #NV-Fehler zurück.

=SVERWEIS(E3;B3:C6;2;FALSCH)

Sie können die WENNNV-Funktion außerhalb der SVERWEIS-Funktion einfügen, um etwas anderes zu tun, wenn die SVERWEIS-Funktion einen #NV-Fehler ergibt. In diesem Beispiel wird „Nicht gefunden“ ausgegeben, wenn der SVERWEIS einen #NV-Fehler ergibt:

=WENNNV(SVERWEIS(E3;B3:C6;2;FALSCH); "Nicht gefunden")

Hinweis: Die neue XLOOKUP-Funktion hat eine integrierte Fehlerbehandlung. Die WENNNV-Funktion wird nicht benötigt!

Eine weitere häufige Verwendung der WENNNV-Funktion besteht darin, einen zweiten SVERWEIS durchzuführen, wenn der erste den Wert nicht finden kann. Dies kann verwendet werden, wenn ein Wert auf einem von zwei Blättern gefunden werden könnte, d. h. wenn der Wert nicht auf dem ersten Blatt gefunden wird, wird er auf dem zweiten Blatt stattdessen gesucht.

=WENNNV(SVERWEIS(E3;B3:C6;2;FALSCH);SVERWEIS(E3;'Daten'!B3:C6;2;FALSCH))

WENN ISTNV in SVERWEIS

Die WENNNV-Funktion wurde in Excel 2013 eingeführt. Davor mussten Sie die kompliziertere WENN/ISTNV-Kombination verwenden:

=WENN(ISTNV(SVERWEIS(E3;B3:C6;2;FALSCH)); "Nicht gefunden";SVERWEIS(E3;B3:C6;2;FALSCH))

Die ISTNV-Funktion prüft, ob das Ergebnis der SVERWEIS-Formel ein #NV-Fehler ist und gibt entsprechend WAHR oder FALSCH zurück. Wenn es WAHR entspricht (d.h. Ihr Suchwert fehlt im Nachschlage-Array), kehrt die WENN-Funktion mit einer von Ihnen angegebenen Meldung zurück, andernfalls gibt sie das Ergebnis der SVERWEIS-Funktion aus.

WENNFEHLER – SVERWEIS

Wie oben erwähnt, testet die WENNNV-Funktion, ob die Formel nur einen #NV-Fehler ausgibt. Stattdessen kann die WENNFEHLER-Funktion verwendet werden, um zu prüfen, ob JEDER Fehler zurückgegeben wird:

=WENNFEHLER(SVERWEIS(E3;B3:C6;2;FALSCH); "Nicht gefunden")

Normalerweise ist es besser, WENNNV anstelle von WENNFEHLER zu verwenden, da WENNFEHLER Fehler behandelt, die Ihre Aufmerksamkeit erfordern könnten.

WENN, ISTNV & IFNA in SVERWEIS – Google Sheets

Diese Formeln funktionieren in Google Sheets auf die gleiche Weise wie in Excel.

Hinweis: die Funktion IFNA behält ihre englische Bezeichnung auch in der deutschen Version von Google Sheets bei (d. h. WENNNV ergibt einen Syntaxfehler).