Alle Permutationen in Excel generieren

In diesem Tutorial zeigen wir Ihnen, wie Sie alle Permutationen in Excel generieren können.

Alle Permutationen generieren

Mit einem VBA-Makro können Sie alle möglichen Permutationen eines bestimmten Zeichensatzes generieren. Dazu müssen Sie lediglich einen kleinen Code erstellen und die Eingabezeichen eingeben.

1. Gehen Sie in der Menüleiste auf Entwicklertools > Visual Basic. Wenn Sie diese Hauptregisterkarte nicht zur Verfügung haben, finden Sie heraus, wie Sie die Registerkarte Entwicklertools hinzufügen können.

2. Gehen Sie im VBA-Fenster auf Einfügen > Modul.

3. Fügen Sie im Codefenster auf der rechten Seite den folgenden Code ein und speichern Sie ihn.

Sub ZeichenketteErhalten()
    Dim xStr As String
    Dim ErsteZeile As Long
    Dim xBildschirm As Boolean
    xBildschirm = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xStr = Application.InputBox("Geben Sie den zu permutierenden Text ein:", "Permutation", , , , , , 2)
    If Len(xStr) < 2 Then Exit Sub
    If Len(xStr) >= 8 Then
        MsgBox "Zu viele Permutationen!", vbInformation, "Permutation"
        Exit Sub
    Else
        ActiveSheet.Columns(1).Clear
        ErsteZeile = 1
        Call PermutationErhalten("", xStr, ErsteZeile)
    End If
    Application.ScreenUpdating = xBildschirm
End Sub
Sub PermutationErhalten(Str1 As String, Str2 As String, ByRef xZeile As Long)
    Dim i As Integer, xLen As Integer
    xLen = Len(Str2)
    If xLen < 2 Then
        Range("A" & xZeile) = Str1 & Str2
        xZeile = xZeile + 1
    Else
        For i = 1 To xLen
            Call PermutationErhalten(Str1 + Mid(Str2, i, 1), Left(Str2, i - 1) + Right(Str2, xLen - i), xZeile)
        Next
    End If
End Sub

4. Jetzt haben Sie das Makro ZeichenketteErhalten erstellt und können es ausführen. Gehen Sie in der Menüleiste auf Entwicklertools > Makros.

5. Wenn es nicht bereits ausgewählt ist, wählen Sie das Makro aus und klicken Sie auf Ausführen.

6. Geben Sie im Pop-up-Fenster die Zeichen für die Permutation ein (hier: abcde) und klicken Sie auf OK.

Als Ergebnis erhalten Sie in Spalte A alle möglichen (120) Permutationen der eingegebenen Zeichen.

Zusätzlich zu dem oben beschriebenen Makro verfügt Excel über eine eingebaute Funktion namens VARIATIONEN, mit der Sie berechnen können, wie viele Permutationen für beliebige Zahlen auftreten können. Diese Funktion funktioniert nur mit Zahlen und nicht mit Text.