Return to Excel Formulas List

SOMME avec une Fonction RECHERCHEV – Excel et Google Sheets

Download Example Workbook

Télécharger le Classeur Exemple

Ce tutoriel montre comment additionner les résultats de plusieurs fonctions RECHERCHEV dans une formule dans Excel et Google Sheets.

somme recherchev fonction principale

 

SOMME avec RECHERCHEV

La fonction RECHERCHEV permet de consulter une seule valeur, mais en créant une formule de tableau, vous pouvez consulter et additionner plusieurs valeurs à la fois.

Cet exemple montre comment calculer le revenu total des ventes d’un magasin spécifique sur 3 mois en utilisant une fonction tableau avec SOMME et VLOOKUP :

=SOMME(RECHERCHEV(P3;B3:N6;{2.3.4};FAUX)

somme recherchev exemple revenus ventes magasin 2

Cette formule de tableau est équivalente à l’utilisation des 3 fonctions RECHERCHEV ordinaires suivantes pour additionner les recettes des mois de janvier, février et mars.

=RECHERCHEV(P3;B3:N6;2;FAUX)+RECHERCHEV(P3;B3:N6;3;FAUX)+RECHERCHEV(P3;B3:N6;4;FAUX)=

somme recherchev exemple revenus formule detaillee

Nous pouvons combiner ces fonctions ensemble en procédant comme suit :

Tout d’abord, nous configurons la fonction RECHERCHEV pour qu’elle renvoie les colonnes 2, 3 et 4 sous forme de tableau (entouré de parenthèses) :

=RECHERCHEV(P3;B3:N6;{2.3.4};FAUX)

Cela produira le résultat du tableau :

{98, 20, 76}

Ensuite, pour additionner les résultats du tableau, nous utilisons la fonction SOMME.

Important ! Si vous utilisez les versions 2019 ou antérieures d’Excel, vous devez entrer la formule en appuyant sur CTRL + MAJ + ENTRÉE pour créer la formule de tableau. Vous saurez que vous l’avez fait correctement, lorsque les accolades apparaissent autour de la formule. Cette opération n’est pas nécessaire dans Excel 365 (ou dans les versions plus récentes d’Excel).

Utilisation de Tableaux de plus Grande Taille dans une Fonction RECHERCHEV

Nous pouvons étendre la taille du tableau d’entrée pour représenter davantage de données. L’exemple suivant calcule le chiffre d’affaires total d’une succursale spécifique sur 12 mois en utilisant une fonction tableau contenant la fonction SOMME pour combiner 12 utilisations de la fonction RECHERCHEV dans une seule cellule.

{=SOMME(RECHERCHEV(P3;B3:N6;{2.3.4.5.6.7.8.9.10.11.12.13};FAUX))}

somme recherchev exemple revenus annuels tableau grande taille

Autres fonctions de synthèse et RECHERCHEV

D’autres fonctions de synthèse peuvent être utilisées de la même manière que la fonction SOMME pour produire d’autres statistiques de synthèse. Par exemple, nous pouvons utiliser les fonctions MAX, MIN, MOYENNE, MEDIANE, SOMME et NB pour résumer le produit des ventes de janvier à mars :

=MAX(RECHERCHEV(J3;B3:H6;{2.3.4};FAUX))
=MIN(RECHERCHEV(J3;B3:H6;{2.3.4};FAUX))
=MOYENNE(RECHERCHEV(J3;B3:H6;{2.3.4};FAUX))
=MEDIANE(RECHERCHEV(J3;B3:H6;{2.3.4};FAUX))
=SOMME(RECHERCHEV(J3;B3:H6;{2.3.4};FAUX))
=NB(RECHERCHEV($J3;$B$3:$H$6;{2.3.4};FAUX))

somme recherchev exemples autres fonctions

Verrouillage des Références de Cellule

Pour faciliter la lecture de nos formules, nous avons présenté les formules sans les références de cellule verrouillées :

=SOMME(RECHERCHEV(P3;B3:N6;{2.3.4};FAUX))

Mais ces formules ne fonctionneront pas correctement lorsqu’elles seront copiées et collées ailleurs dans votre fichier. Vous devez plutôt utiliser des références de cellules verrouillées comme ceci :

=SOMME(RECHERCHEV(P3;$B$3:$N$6;{2.3.4};FAUX))

Pour en savoir plus, lisez notre article sur le verrouillage des références de cellule.

SOMME avec RECHERCHEV dans Google Sheets

Ces formules fonctionnent de la même manière dans Google Sheets et dans Excel, sauf que la fonction ARRAYFORMULA doit être utilisée dans Google Sheets pour que les résultats soient évalués correctement. Celle-ci peut être ajoutée automatiquement en appuyant sur les touches CTRL + MAJ + ENTRÉE lors de l’édition de la formule.

=ARRAYFORMULA(SOMME(RECHERCHEV(P5;B5:N8;{2\3\4};FAUX)))

somme recherchev google sheets

Excel Practice Worksheet

practice excel worksheet

Practice Excel functions and formulas with our 100% free practice worksheets!

  • Automatically Graded Exercises
  • Learn Excel, Inside Excel!

Free Download

Return to Excel Formulas List