Encontrar Valores Perdidos – Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial mostrará cómo comprobar si faltan elementos en una lista en Excel y Google Sheets.
Encontrar los valores que faltan
Hay varias formas de comprobar si faltan elementos en una lista.
Buscar valores que faltan con CONTAR.SI
Una forma de encontrar los valores que faltan en una lista es utilizar la función CONTAR.SI junto con la función SI.
=SI(CONTAR.SI(B3:B7;D3);"Si";"Falta")
Veamos cómo funciona esta fórmula.
Función CONTAR.SI
La función CONTAR.SI cuenta el número de celdas que cumplen un criterio determinado. Si ninguna celda cumple la condición, devuelve cero.
=CONTAR.SI(B3:B7;D3)
En este ejemplo, «#1103» y «#7682» están en la columna B, por lo que la fórmula nos da 1 para cada uno. «#5555» no está en la lista, por lo que la fórmula nos da 0.
Función SI
La función SI evaluará cualquier número distinto de cero como VERDADERO, y cero como FALSO. Dentro de la función SI, realizamos nuestro recuento, y luego la salida «Sí» para VERDADERO y «Falta» para FALSO. Esto nos da nuestra fórmula original de:
=SI(CONTAR.SI(B3:B7;D3);"Si";"Falta")
Encontrar los valores que faltan con BUSCARV
Otra forma de encontrar valores faltantes en una lista es utilizar las funciones BUSCARV e ESNOD junto con la función SI.
=SI(ESNOD(BUSCARV(D3;B3:B7;1;FALSO));"Falta";"Si")
Repasemos esta fórmula.
Función BUSCARV
Comience por realizar un BUSCARV de coincidencia exacta (FALSO) para los valores de su lista.
=BUSCARV(D3;B3:B7;1;FALSO)
Si se encuentra el elemento, la función BUSCARV devolverá ese elemento, de lo contrario devolverá el error #N/D.
Función ESNOD
Puede utilizar la función ESNOD para convertir los errores #N/D en VERDADERO, indicando que esos valores faltan.
=ESNOD(E3)
Todos los valores no erróneos resultan en FALSO.
Función SI
A continuación, convierta los resultados de la Función ESNOD para mostrar si el valor falta. Si la Función BUSCARV nos dio un error, el elemento es «Faltante».
=SI(F3;"Falta";"Si")
El elemento en ambas listas muestra «Sí».
Combinando estos pasos obtenemos la fórmula original
=SI(ESNOD(BUSCARV(D3;B3:B7;1;FALSO));"Falta";"Si")Buscar valores que faltan en Google Sheets
Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.
